QtのCMakeデプロイメントAPI

cmake_minimum_required(VERSION 3.22)
project(MyApp)

find_package(Qt6 REQUIRED COMPONENTS Widgets)
qt_standard_project_setup()

qt_add_executable(MyApp main.cpp)
target_link_libraries(MyApp PRIVATE Qt::Widgets)

install(TARGETS MyApp
    BUNDLE  DESTINATION .
    RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
)

qt_generate_deploy_app_script(
    TARGET MyApp
    OUTPUT_SCRIPT deploy_script
    NO_UNSUPPORTED_PLATFORM_ERROR
)
install(SCRIPT ${deploy_script})

qt_generate_deploy_app_scriptの呼び出しは、ビルドディレクトリにCMakeスクリプトファイルを生成し、次の2つのことを行います。

• QtDeploySupport.cmakeファイルを含める
• インストールされた実行可能ファイルに対してqt6_deploy_runtime_dependenciesを呼び出す

QtDeploySupport.cmakeファイルは、デプロイメントを補助するためのCMakeコマンドを提供します。また、QT_DEPLOY_PREFIXなどの変数も設定します。

qt_deploy_runtime_dependenciesコマンドは、デプロイメントプロセスの実際のドライバーです。mac/windeployqtを呼び出し、必要に応じてqt.confファイルを生成します。

カスタマイズが必要なセットアップでは、スクリプトの生成を自分で行う必要があります。

set(deploy_script "${CMAKE_CURRENT_BINARY_DIR}/deploy_MyApp.cmake")
file(GENERATE OUTPUT ${deploy_script} CONTENT "
include(\"${QT_DEPLOY_SUPPORT}\")

qt_deploy_runtime_dependencies(
    EXECUTABLE \"\${QT_DEPLOY_BIN_DIR}/$<TARGET_FILE_NAME:MyApp>\"
    GENERATE_QT_CONF
)")

初期のincludeステートメントでは、設定時に使用可能なCMake変数QT_DEPLOY_SUPPORTを展開する必要があります。

スクリプトの残りの部分では、インストール時に利用可能なQT_DEPLOY_BIN_DIR変数にアクセスします。そのため、変数の代入を設定時に行わないように、エスケープする必要があります。

最後に、generator式を使用してMyAppターゲットのファイル名を抽出します。

プロジェクトが独自のqt.confを提供している場合、qt_deploy_runtime_dependenciesがそれを生成しないようにしたい場合は、GENERATE_QT_CONFを削除できます。

Qt の CMake デプロイメント API は、GNUInstallDirs.cmake で定義された CMAKE_INSTALL_BINDIR 変数と CMAKE_INSTALL_LIBDIR 変数を使用してステージング領域のレイアウトを決定します。

インストール時に、これらのディレクトリ変数は QT_DEPLOY_BIN_DIR と QT_DEPLOY_LIB_DIR として利用できます。

実行可能ファイルのインストール・コマンドの DESTINATION には CMAKE_INSTALL_BINDIR を、ライブラリのインストール・コマンドの DESTINATION には CMAKE_INSTALL_LIBDIR を必ず使用してください。

CMAKE_INSTALL_BINDIR や CMAKE_INSTALL_LIBDIR の値を変更するには、Qt6Core パッケージが見つかる前に変数を設定してください。

Qt プラグインは QT_DEPLOY_PLUGINS_DIR に配置され、デフォルトは 「plugin」です。QML モジュールは QT_DEPLOY_QML_DIR に配置され、デフォルトは「qml」です。

QtQuickプロジェクトの配布

QtQuickプロジェクトのデプロイは少し複雑ですが、ユーザーにとっては幸いなことに、そうではありません。詳細はqt_generate_deploy_qml_app_scriptコマンドによって隠ぺいされています。

QtQuick アプリケーションの CMakeLists.txt を作成する方法を見てみましょう。

まず、QtQuickアプリケーションを作成します。

qt_add_executable(MyApp main.cpp)
qt_add_qml_module(MyApp
    URI Application
    VERSION 1.0
    QML_FILES main.qml MyThing.qml
)

通常のinstallコマンドを追加する必要があります。

install(TARGETS MyApp
    BUNDLE  DESTINATION .
    RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
)

そして、qt_generate_deploy_qml_app_scriptを呼び出します。

qt_generate_deploy_qml_app_script(
    TARGET MyApp
    OUTPUT_SCRIPT deploy_script
)
install(SCRIPT ${deploy_script})

インストール時に、QML ファイルとプロジェクトで使用する Qt の部分を含むアプリケーションバイナリがデプロイされます。

qt_generate_deploy_qml_app_script は qt_deploy_runtime_dependencies に加えて qt_deploy_qml_imports を呼び出します。詳細はこれらのコマンドのドキュメントを参照してください。

現時点では、Qt の CMake デプロイメント API は Windows と macOS でのみサポートされています。Android はビルドターゲット経由で処理されます。

将来的には Linux (QTBUG-74940) を含む、より多くのプラットフォームを追加する予定です。

CMake デプロイメント API は当分の間テクニカルプレビューです。お好きなプロジェクトでお試しいただき、https://bugreports.qt.io/ にフィードバックをお寄せください。